File:Tidallock.gif

Summary[edit]

Mathematica 11.0 code[edit]

(*To make the calculation simpler the satellite has its mass \
concentrated in only two points (a spherically symmetric satellite \
won't show any tidal locking)*)

d = 1.; (*half-distance between the two points with mass*)

m0 = 10; (*mass of the mai n body*)
mp = 1; (*mass of each massive \
point on the satellite*)
p1 = 
 r[t] {Cos[\[Theta][t]], Sin[\[Theta][t]]} + 
  d {Cos[\[Phi][t]], Sin[\[Phi][t]]};
p2 = r[t] {Cos[\[Theta][t]], Sin[\[Theta][t]]} - 
   d {Cos[\[Phi][t]], Sin[\[Phi][t]]};
T1 = mp/2 FullSimplify[Norm[D[p1, t] ]^2, 
   Assumptions -> {r[t] > 0, 
     r'[t] \[Element] Reals, \[Theta][t] \[Element] 
      Reals, \[Phi][t] \[Element] Reals, \[Theta]'[t] \[Element] 
      Reals, \[Phi]'[t] \[Element] Reals}]
T2 = mp/2 FullSimplify[Norm[D[p2, t] ]^2, 
   Assumptions -> {r[t] > 0, 
     r'[t] \[Element] Reals, \[Theta][t] \[Element] 
      Reals, \[Phi][t] \[Element] Reals, \[Theta]'[t] \[Element] 
      Reals, \[Phi]'[t] \[Element] Reals}]
V1 = (-m0 mp)/
 FullSimplify[Norm[p1], 
  Assumptions -> {r > 0, t \[Element] Reals, f \[Element] Reals}]
V2 = (-m0 mp)/
 FullSimplify[Norm[p2], 
  Assumptions -> {r > 0, t \[Element] Reals, f \[Element] Reals}]
L = FullSimplify[T1 + T2 - V1 - V2, 
  Assumptions -> {r[t] > 0, 
    r'[t] \[Element] Reals, \[Theta][t] \[Element] 
     Reals, \[Phi][t] \[Element] Reals, \[Theta]'[t] \[Element] 
     Reals, \[Phi]'[t] \[Element] Reals}]
(*Euler-Lagrange equations*)

e1 = FullSimplify[D[D[L, \[Theta]'[t]], t] - D[L, \[Theta][t]]];
e2 = FullSimplify[D[D[L, \[Phi]'[t]], t] - D[L, \[Phi][t]]];
e3 = FullSimplify[D[D[L, r'[t]], t] - D[L, r[t]]]

tmax = 5000;
r0 = 6; (*starting distance of the satellite*)
s1 = 
 NDSolve[{e1 == 0, e2 == 0, 
   e3 == 0, \[Theta][0] == 0, \[Phi][0] == 0.8, 
   r[0] == r0, \[Theta]'[0] == 0.25, \[Phi]'[0] == 0.2, 
   r'[0] == 0}, {\[Theta], \[Phi], r}, {t, 0, tmax}, 
  MaxSteps -> Infinity]

plots = Table[
   Graphics[{Disk[{0, 0}, 2], Thick, 
     Circle[({r[t] Cos[\[Theta][t]], r[t] Sin[\[Theta][t]]} /. s1)[[
       1]], d], Orange,
     Disk[(p1 /. s1)[[1]], 0.5], Purple, Disk[(p2 /. s1)[[1]], 0.5]
     }, PlotRange -> {{-15, 15}, {-15, 15}}]
   , {t, 3900, 4800, 0.5}];
ListAnimate[plots]

Licensing[edit]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

This file, which was originally posted to https://twitter.com/j_bertolotti/status/1030470604418428929, was reviewed on 29 November 2018 by reviewer Ronhjones, who confirmed that it was available there under the stated license on that date.